Version bump

gui-libs/wlroots/wlroots-0.16.2-r2.ebuild

@@ -0,0 +1,97 @@
+# Copyright 1999-2023 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson
+
+DESCRIPTION="Pluggable, composable, unopinionated modules for building a Wayland compositor"
+HOMEPAGE="https://gitlab.freedesktop.org/wlroots/wlroots"
+
+if [[ ${PV} == 9999 ]]; then
+	EGIT_REPO_URI="https://gitlab.freedesktop.org/${PN}/${PN}.git"
+	inherit git-r3
+	SLOT="0/9999"
+else
+	SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/archive/${PV}/${P}.tar.gz"
+	KEYWORDS="amd64 arm64 ~loong ~ppc64 ~riscv x86"
+	SLOT="0/$(ver_cut 2)"
+fi
+
+LICENSE="MIT"
+IUSE="+drm +libinput tinywl vulkan x11-backend X phoc"
+
+DEPEND="
+	>=dev-libs/wayland-1.21.0
+	>=dev-libs/wayland-protocols-1.28
+	drm? ( sys-apps/hwdata:= )
+	libinput? ( >=dev-libs/libinput-1.14.0:0= )
+	media-libs/mesa[egl(+),gles2]
+	sys-auth/seatd:=
+	virtual/libudev
+	vulkan? (
+		dev-util/glslang:0=
+		dev-util/vulkan-headers:0=
+		media-libs/vulkan-loader:0=
+	)
+	>=x11-libs/libdrm-2.4.114:0=
+	x11-libs/libxkbcommon
+	>=x11-libs/pixman-0.42.0:0=
+	x11-backend? ( x11-libs/libxcb:0= )
+	X? (
+		x11-base/xwayland
+		x11-libs/libxcb:0=
+		x11-libs/xcb-util-image
+		x11-libs/xcb-util-renderutil
+		x11-libs/xcb-util-wm
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+BDEPEND="
+	>=dev-libs/wayland-protocols-1.24
+	>=dev-util/meson-0.60.0
+	dev-util/wayland-scanner
+	virtual/pkgconfig
+"
+
+src_prepare() {
+	if use phoc; then
+		PATCHES+=( "${FILESDIR}"/0001-Revert-layer-shell-error-on-0-dimension-without-anch.patch )
+	fi
+	default
+}
+
+src_configure() {
+	local backends=(
+		$(usev drm)
+		$(usev libinput)
+		$(usev x11-backend 'x11')
+	)
+	# Separate values with a comma with this evil floating point bit hack
+	local meson_backends=$(IFS=','; echo "${backends[*]}")
+	# xcb-util-errors is not on Gentoo Repository (and upstream seems inactive?)
+	local emesonargs=(
+		"-Dxcb-errors=disabled"
+		$(meson_use tinywl examples)
+		-Drenderers=$(usex vulkan 'gles2,vulkan' gles2)
+		$(meson_feature X xwayland)
+		-Dbackends=${meson_backends}
+	)
+
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	if use tinywl; then
+		dobin "${BUILD_DIR}"/tinywl/tinywl
+	fi
+}
+
+pkg_postinst() {
+	elog "You must be in the input group to allow your compositor"
+	elog "to access input devices via libinput."
+}